grim/guifications3

closing this since most of it will happen on default since libgds now exists ;)
the_plugin_problem
2010-12-20, Gary Kramlich
1f195d42369a
closing this since most of it will happen on default since libgds now exists ;)
dnl Process this file with autoconf to create configure.
dnl ################################################################
dnl # Initialize autoconf
dnl ################################################################
AC_INIT(gflib, 0.0.1dev, guifications-devel@lists.guifications.org)
AC_PREREQ(2.50)
AC_CANONICAL_SYSTEM
AC_CONFIG_SRCDIR(config.h.in)
AC_COPYRIGHT([Copyright 2003-2009 Gary Kramlich])
dnl ################################################################
dnl # Version information
dnl ################################################################
GFLIB_MAJOR_VERSION=0
GFLIB_MINOR_VERSION=0
GFLIB_MICRO_VERSION=1
GFLIB_DEVEL_VERSION=0
GFLIB_VERSION=$GFLIB_MAJOR_VERSION.$GFLIB_MINOR_VERSION.$GFLIB_MICRO_VERSION
if test "x$GFLIB_DEVEL_VERSION" != "x0"; then
if test "x$GFLIB_MICRO_VERSION" = "x0"; then
GFLIB_MICRO_VERSION=$GFLIB_DEVEL_VERSION
GFLIB_VERSION=$GFLIB_MAJOR_VERSION.$GFLIB_MINOR_VERSION.$GFLIB_MICRO_VERSION
else
GFLIB_VERSION=$GFLIB_VERSION.$GFLIB_DEVEL_VERSION
fi
fi
AC_DEFINE_UNQUOTED(GFLIB_MAJOR_VERSION, $GFLIB_MAJOR_VERSION, [gflib major version.])
AC_DEFINE_UNQUOTED(GFLIB_MINOR_VERSION, $GFLIB_MINOR_VERSION, [gflib minor version.])
AC_DEFINE_UNQUOTED(GFLIB_MICRO_VERSION, $GFLIB_MICRO_VERSION, [gflib micro version.])
AC_DEFINE_UNQUOTED(GFLIB_VERSION, $GFLIB_VERSION, [gflib version])
AC_DEFINE_UNQUOTED(GFLIB_VERSION_S, "$GFLIB_VERSION", [gflib version string])
dnl ################################################################
dnl # libtool versioning
dnl ################################################################
dnl #
dnl # +1 : 0 : +1 == new interface that does not break old one.
dnl # +1 : 0 : 0 == removed an interface. Breaks old apps.
dnl # ? : +1 : ? == internal changes that doesn't break anything.
dnl #
dnl # CURRENT : REVISION : AGE
dnl #
LT_CURRENT=0
LT_REVISION=0
LT_AGE=0
LT_RELEASE=$GFLIB_MAJOR_VERSION.$GFLIB_MINOR_VERSION.$GFLIB_MICRO_VERSION
AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)
dnl ################################################################
dnl # Initialize automake
dnl ################################################################
AM_INIT_AUTOMAKE([gnu dist-bzip2])
dnl ################################################################
dnl # Configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h)
dnl # Stash configure args
AC_DEFINE_UNQUOTED(CONFIG_ARGS, "$ac_configure_args", [configure arguments])
# set our language to C
AC_LANG([C])
dnl #######################################################################
dnl # Make sure we have pkg-config
dnl #######################################################################
PKG_PROG_PKG_CONFIG
dnl #######################################################################
dnl # Setup libtool
dnl #######################################################################
LT_INIT
LT_LANG([C])
LIBTOOL="$LIBTOOL --silent"
dnl #######################################################################
dnl # I'm lazy and figured config.h is the best place for this ;)
dnl #######################################################################
AC_DEFINE_UNQUOTED(GFLIB_WEBSITE, "http://guifications.org/", [gflib website])
dnl #######################################################################
dnl # Our header
dnl #######################################################################
AH_TOP([ /* our header */
#ifndef CONFIG_H
#define CONFIG_H
])
AH_BOTTOM([
#endif /* CONFIG_H */
])
dnl #######################################################################
dnl # INTLTOOL
dnl #######################################################################
AC_PROG_INTLTOOL
GETTEXT_PACKAGE=gflib
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
ALL_LINGUAS=""
AM_GLIB_GNU_GETTEXT
AC_OUTPUT_COMMANDS(
[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
esac])
dnl #######################################################################
dnl # Look for the C compiler
dnl #######################################################################
AC_MSG_CHECKING([WMD's])
AC_MSG_RESULT(no)
CFLAGS_save="$CFLAGS"
AC_PROG_CC
CFLAGS="$CFLAGS_save"
AC_ARG_ENABLE(debug,
AC_HELP_STRING([--enable-debug],[compile with debugging support])
,,enable_debug=no)
if test x"$enable_debug" = x"yes" ; then
AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])
fi
if test x"$GCC" = x"yes"; then
CFLAGS="$CFLAGS -Wall -g3"
fi
AC_SUBST(CFLAGS)
dnl #######################################################################
dnl # Check for python (this is just used for random stuff right now)
dnl #######################################################################
AC_PATH_PROG([PYTHON], [python], [no])
AC_SUBST(PYTHON)
AM_CONDITIONAL([HAVE_PYTHON], test x"$PYTHON" != x"no")
dnl #######################################################################
dnl # check for glib and other glib dependencies
dnl #######################################################################
PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.16.0 gobject-2.0 >= 2.16.0 gthread-2.0 >= 2.16.0])
AC_SUBST(GLIB_CFLAGS)
AC_SUBST(GLIB_LIBS)
GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
AC_SUBST(GLIB_GENMARSHAL)
GLIB_MKENUMS=`pkg-config --variable=glib_mkenums glib-2.0`
AC_SUBST(GLIB_MKENUMS)
PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.16.0])
AC_SUBST(GMODULE_CFLAGS)
AC_SUBST(GMODULE_LIBS)
dnl #######################################################################
dnl # GtkDoc stuff
dnl #######################################################################
GTK_DOC_CHECK([1.0])
dnl #######################################################################
dnl # Finish up
dnl #######################################################################
AC_OUTPUT([Makefile
gflib.pc
contrib/Makefile
doc/Makefile
doc/gflib/Makefile
doc/gflib-genheader.1
doc/gflib-query-plugins.1
gflib/Makefile
po/Makefile.in
po-properties/Makefile.in
tests/Makefile
])
dnl #######################################################################
dnl # Ouput!!
dnl #######################################################################
echo;
echo AC_PACKAGE_NAME AC_PACKAGE_VERSION Configuration complete
echo;
echo Debugging enabled................: $enable_debug
echo;
echo Type make to compile
echo;