grim/guifications3

kill this branch since it still uses the old mtn rfqdn branch names and it's very out of date
org.guifications.gf3.feed_rewrite
2009-12-06, Gary Kramlich
1365e67470a8
kill this branch since it still uses the old mtn rfqdn branch names and it's very out of date
dnl Process this file with autoconf to create configure.
dnl ################################################################
dnl # Initialize autoconf
dnl ################################################################
AC_INIT(gflib-dbus, 3.0.0mtn, guifications-devel@lists.guifications.org)
AC_PREREQ(2.50)
AC_CANONICAL_SYSTEM
AC_CONFIG_SRCDIR(config.h.in)
AC_COPYRIGHT([Copyright 2005-2007 Gary Kramlich])
dnl ################################################################
dnl # Initialize automake
dnl ################################################################
AM_INIT_AUTOMAKE([foreign dist-bzip2])
dnl # disable the static library
AC_DISABLE_STATIC
dnl ################################################################
dnl # Configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h)
dnl # Stash configure args
AC_DEFINE_UNQUOTED(CONFIG_ARGS, "$ac_configure_args", [configure arguments])
dnl #######################################################################
dnl # Setup libtool
dnl #######################################################################
AM_PROG_LIBTOOL
LIBTOOL="$LIBTOOL --silent"
dnl #######################################################################
dnl # Some helper stuff, well mainly because I'm lazy :)
dnl #######################################################################
AC_DEFINE_UNQUOTED(GFLIB_DBUS_WEBSITE, "http://guifications.org/", [gflib-dbus website])
GF_DBUS_SERVICE="org.guifications"
AC_SUBST(GF_DBUS_SERVICE)
GF_DBUS_PATH="/org/guifications/"
AC_SUBST(GF_DBUS_PATH)
dnl #######################################################################
dnl # Our header
dnl #######################################################################
AH_TOP([ /* our header */
#ifndef CONFIG_H
#define CONFIG_H
])
AH_BOTTOM([
#endif /* CONFIG_H */
])
AC_MSG_CHECKING([absolutely nothing])
AC_MSG_RESULT([yes])
dnl #######################################################################
dnl # intltool
dnl #######################################################################
AC_PROG_INTLTOOL
GETTEXT_PACKAGE=gflib-dbus
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
ALL_LINGUAS=""
AM_GLIB_GNU_GETTEXT
AC_OUTPUT_COMMANDS(
[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
esac])
dnl #######################################################################
dnl # Look for the C compiler
dnl #######################################################################
CFLAGS_save="$CFLAGS"
AC_PROG_CC
CFLAGS="$CFLAGS_save"
AC_ARG_ENABLE(debug, [ --enable-debug compile with debugging support],,enable_debug=no)
if test "x$enable_debug" = "xyes" ; then
AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])
if test "x$GCC" = "xyes"; then
CFLAGS="$CFLAGS -Wall -g3"
fi
fi
AC_SUBST(CFLAGS)
dnl #######################################################################
dnl # check for gflib and gflib-plugin
dnl #######################################################################
PKG_CHECK_MODULES(GFLIB, gflib)
AC_SUBST(GFLIB_LIBS)
AC_SUBST(GFLIB_CFLAGS)
GFLIB_GENHEADER=`pkg-config --variable=gflib_genheader gflib`
AC_SUBST(GFLIB_GENHEADER)
if test x"${prefix}" = x"NONE" ; then
GFLIB_PLUGIN_DIR=`pkg-config --variable=plugin_dir gflib`
else
GFLIB_PLUGIN_DIR="${prefix}/lib/guifications/"
fi
AC_SUBST(GFLIB_PLUGIN_DIR)
dnl #######################################################################
dnl # check for glib and other glib dependencies
dnl #######################################################################
PKG_CHECK_MODULES(GLIB, glib-2.0 gobject-2.0)
AC_SUBST(GLIB_CFLAGS)
AC_SUBST(GLIB_LIBS)
dnl #######################################################################
dnl # D-BUS Stuff
dnl #######################################################################
PKG_CHECK_MODULES(DBUS, dbus-1 >= 0.62 dbus-glib-1 >= 0.62)
AC_SUBST(DBUS_CFLAGS)
AC_SUBST(DBUS_LIBS)
AC_MSG_CHECKING([dbus version])
DBUS_VERSION=`$PKG_CONFIG --modversion dbus-1`
DBUS_MAJOR_VERSION=`echo $DBUS_VERSION | cut -d. -f 1`
DBUS_MINOR_VERSION=`echo $DBUS_VERSION | cut -d. -f 2`
DBUS_MICRO_VERSION=`echo $DBUS_VERSION | cut -d. -f 3`
AC_MSG_RESULT($DBUS_VERSION)
AC_DEFINE_UNQUOTED(DBUS_MAJOR_VERSION, $DBUS_MAJOR_VERSION, [D-BUS major version.])
AC_DEFINE_UNQUOTED(DBUS_MINOR_VERSION, $DBUS_MINOR_VERSION, [D-BUS minor version.])
AC_DEFINE_UNQUOTED(DBUS_MICRO_VERSION, $DBUS_MICRO_VERSION, [D-BUS micro version.])
dnl #######################################################################
dnl # Finish up
dnl #######################################################################
AC_OUTPUT([Makefile
gflib-dbus/Makefile
pixmaps/Makefile
po/Makefile.in
po-properties/Makefile.in
])
dnl #######################################################################
dnl # Ouput!!
dnl #######################################################################
echo;
echo AC_PACKAGE_NAME AC_PACKAGE_VERSION Configuration complete
echo;
echo Debugging enabled................: $enable_debug
echo;
echo gflib plugin directory...........: $GFLIB_PLUGIN_DIR
echo;
echo D-BUS version....................: $DBUS_VERSION
echo;
echo Type make to compile
echo;