gplugin/gplugin

Bump version numbers for the 0.28.2 release
develop v0.28.2
2019-10-31, Gary Kramlich
1924632f9d60
Bump version numbers for the 0.28.2 release
###############################################################################
# Project Info
###############################################################################
project('gplugin', 'c', version : '0.28.2',
meson_version : '>=0.42.0',
default_options : ['c_std=c99'])
parts = meson.project_version().split('-')
if parts.length() > 1
extra = parts[1]
else
extra = ''
endif
parts = parts[0].split('.')
GPLUGIN_MAJOR_VERSION = parts[0]
version_conf = configuration_data()
version_conf.set('GPLUGIN_MAJOR_VERSION', GPLUGIN_MAJOR_VERSION)
version_conf.set('GPLUGIN_MINOR_VERSION', parts[1])
version_conf.set('GPLUGIN_MICRO_VERSION', parts[2])
version_conf.set('GPLUGIN_EXTRA_VERSION', extra)
version_conf.set('GPLUGIN_VERSION', meson.project_version())
LOCALE_DIR = join_paths(get_option('prefix'), get_option('localedir'))
add_project_arguments('-DLOCALEDIR="@0@"'.format(LOCALE_DIR), language : 'c')
###############################################################################
# Dependencies
###############################################################################
gnome = import('gnome')
pkgconfig = import('pkgconfig')
if get_option('help2man')
help2man = find_program('help2man')
endif
GLIB = dependency('glib-2.0', version : '>=2.40.0')
GOBJECT = dependency('gobject-2.0')
# we separate gmodule out so our test aren't linked to it
GMODULE = dependency('gmodule-2.0')
###############################################################################
# NLS
###############################################################################
GETTEXT_PACKAGE = 'gplugin'
add_project_arguments('-DGETTEXT_PACKAGE="@0@"'.format(GETTEXT_PACKAGE),
language : 'c')
if get_option('nls')
i18n = import('i18n')
endif
###############################################################################
# Build Info
###############################################################################
compiler = meson.get_compiler('c')
add_project_arguments(
'-DPREFIX="@0@"'.format(get_option('prefix')),
'-DLIBDIR="@0@"'.format(get_option('libdir')),
'-DGPLUGIN_WEBSITE="https://bitbucket.org/gplugin/gplugin"',
language : 'c'
)
if compiler.has_argument('-Wformat')
add_project_arguments('-Wformat', language : 'c')
if compiler.has_multi_arguments(['-Wformat', '-Werror=format-security'])
add_project_arguments('-Werror=format-security', language : 'c')
endif
endif
configure_file(
input : 'gplugin-version.sh.in',
output : 'gplugin-version.sh',
configuration : version_conf)
toplevel_inc = include_directories('.')
###############################################################################
# gtk-doc
###############################################################################
ENABLE_DOC = get_option('doc')
if ENABLE_DOC
if meson.version().version_compare('<0.41.2')
error('Meson 0.41.2 or newer is required to build documentation.')
endif
endif
###############################################################################
# Subdirectories
###############################################################################
subdir('gplugin')
subdir('gplugin-gtk')
subdir('gplugin-gtk-viewer')
subdir('packaging')
subdir('plugins')
subdir('po')
subdir('lua')
subdir('perl')
subdir('python')
subdir('tcc')
subdir('vala')
###############################################################################
# Install stuff
###############################################################################
# documentation
install_data('ChangeLog', 'INSTALL.md', 'README.md', 'HACKING',
install_dir : join_paths(get_option('datadir'), 'doc', 'gplugin'))